Example: A Curve of Rank 1

Let $E$ be the elliptic curve with label 37a, which is the curve of rank $1$ with smallest conductor. We define $E$ and compute its rank, which is $1$.

sage: E = EllipticCurve('37a'); E
Elliptic Curve defined by y^2 + y = x^3 - x over 
Rational Field
sage: E.rank()
1

We next compute the value $L'(E,1)$. The corresponding function in SAGE takes a bound on the number of terms of the $L$-series to use, and returns an approximate to $L'(E,1)$ along with a bound on the error (coming from the tail end of the series).

sage: L, error = E.Lseries_deriv_at1(200); L, error
(0.305999773834879, 2.10219814818300e-90)
sage: L = RDF(L); L
0.305999773835

We compute $\Omega_E$ and the Tamagawa number, regulator, and torsion as above.

sage: Om = RDF(E.omega()); Om
5.98691729246
sage: factor(discriminant(E))
37
sage: c37 = 1
sage: Reg = RDF(E.regulator()); Reg
0.05111140824
sage: T = E.torsion_order(); T
1

Finally, we solve and find that the conjectural order of ${\mbox{{\fontencoding{OT2}\fontfamily{wncyr}\fontseries{m}\fontshape{n}\selectfont Sh}}}(E/\mathbb{Q})$ is $1$.

sage: Sha_conj = L * T^2 / (Om * Reg * c37); Sha_conj
1.0